DoboWiki

Dim mail As New System.Web.Mail.MailMessage
'From
mail.From = "xxx@xxx.xxx"
'To
mail.To = "xxx@xxx.xxx"
'Subject
mail.Subject = "テスト"
'本文
mail.Body = "これはテストです。"
 
'ポート番号を指定する
mail.Fields.Item( _
    "http://schemas.microsoft.com/cdo/configuration/smtpserverport") _
    = 25
 
'SMTPサーバーを指定
System.Web.Mail.SmtpMail.SmtpServer = "xxx.xxx.xxx"
'メールを送信
System.Web.Mail.SmtpMail.Send(mail)

Dim t As Type = Type.GetTypeFromProgID("CDO.Message")
Dim cdo As Object = Activator.CreateInstance(t)
 
t.InvokeMember("From", _
    System.Reflection.BindingFlags.SetProperty, _
    Nothing, cdo, New Object() {"xxx@xxx.xxx"})
t.InvokeMember("To", _
    System.Reflection.BindingFlags.SetProperty, _
    Nothing, cdo, New Object() {"xxx@xxx.xxx"})
t.InvokeMember("Subject", _
    System.Reflection.BindingFlags.SetProperty, _
    Nothing, cdo, New Object() {"テスト"})
t.InvokeMember("Textbody", _
    System.Reflection.BindingFlags.SetProperty, _
    Nothing, cdo, New Object() {"これはテストです!!"})
 
Dim conf As Object = t.InvokeMember("Configuration", _
    System.Reflection.BindingFlags.GetProperty, _
    Nothing, cdo, Nothing)
Dim fields As Object = t.InvokeMember("Fields", _
    System.Reflection.BindingFlags.GetProperty, _
    Nothing, conf, Nothing)
t.InvokeMember("Item", _
    System.Reflection.BindingFlags.SetProperty, _
    Nothing, fields, New Object() { _
    "http://schemas.microsoft.com/cdo/configuration/sendusing", _
    2})
'SMTPサーバーを指定する
t.InvokeMember("Item", _
    System.Reflection.BindingFlags.SetProperty, _
    Nothing, fields, New Object() { _
    "http://schemas.microsoft.com/cdo/configuration/smtpserver", _
    "xxx.xxx.xxx"})
'ポート番号を指定する
t.InvokeMember("Item", _
    System.Reflection.BindingFlags.SetProperty, _
    Nothing, fields, New Object() { _
    "http://schemas.microsoft.com/cdo/configuration/smtpserverport", _
    25})
 
t.InvokeMember("Update", _
    System.Reflection.BindingFlags.InvokeMethod, _
    Nothing, fields, New Object() {})
 
'送信する
t.InvokeMember("Send", _
    System.Reflection.BindingFlags.InvokeMethod, _
    Nothing, cdo, New Object() {})

Dim mail As New System.Web.Mail.MailMessage
'From
mail.From = "xxx@xxx.xxx"
'To
mail.To = "xxx@xxx.xxx"
'Subject
mail.Subject = "テスト"
'本文
mail.Body = "これはテストです。"
 
'smtpauthenticateを使う時は必ず2にする
mail.Fields.Item( _
    "http://schemas.microsoft.com/cdo/configuration/sendusing") _
    = 2
'sendusingを2にした時は、必ずサーバーとポートを指定する
'SMTPサーバーを指定
mail.Fields.Item( _
    "http://schemas.microsoft.com/cdo/configuration/smtsperver") _
    = "xxx.xxx.xxx"
'ポート番号を指定する
mail.Fields.Item( _
    "http://schemas.microsoft.com/cdo/configuration/smtpserverport") _
    = 25
 
'認証を使う
'1はbasic認証、2はNTLM認証
mail.Fields.Item( _
    "http://schemas.microsoft.com/cdo/configuration/smtpauthenticate") = 1
'ユーザー名
mail.Fields.Item( _
    "http://schemas.microsoft.com/cdo/configuration/sendusername") _
    = "xxx"
'パスワード
mail.Fields.Item( _
    "http://schemas.microsoft.com/cdo/configuration/sendpassword") _
    = "xxx"
 
System.Web.Mail.SmtpMail.SmtpServer = "xxx.xxx.xxx"
 
'メールを送信
System.Web.Mail.SmtpMail.Send(mail)

Imports System
Imports System.Net.Sockets
Imports System.Text
Imports System.Collections.Specialized
 
Namespace Dobon.Mail
    ''' <summary>
    ''' 送信用のメールメッセージ
    ''' </summary>
    Public Class SmtpMailMessage
        Private _from As String
        ''' <summary>
        ''' 送信者のメールアドレス
        ''' </summary>
        Public Property From() As String
            Get
                Return _from
            End Get
            Set(ByVal Value As String)
                _from = Value
            End Set
        End Property
 
        Private _to As String
        ''' <summary>
        ''' 送信先のメールアドレス
        ''' </summary>
        Public Property [To]() As String
            Get
                Return _to
            End Get
            Set(ByVal Value As String)
                _to = Value
            End Set
        End Property
 
        Private _subject As String
        ''' <summary>
        ''' メールの件名
        ''' </summary>
        Public Property Subject() As String
            Get
                Return _subject
            End Get
            Set(ByVal Value As String)
                _subject = Value
            End Set
        End Property
 
        Private _body As String
        ''' <summary>
        ''' メールの本文
        ''' </summary>
        Public Property Body() As String
            Get
                Return _body
            End Get
            Set(ByVal Value As String)
                _body = Value
            End Set
        End Property
    End Class
 
    ''' <summary>
    ''' SMTPでメールを送信する
    ''' </summary>
    Public Class Smtp
        ''' <summary>
        ''' エントリポイント
        ''' </summary>
        Public Shared Sub Main()
            Dim mail As New SmtpMailMessage
            'From
            mail.From = "xxx@xxx.xxx"
            'To
            mail.To = "xxx@xxx.xxx"
            'Subject
            mail.Subject = "テスト"
            '本文
            mail.Body = "これはテストです。"
 
            Dim smtp As New Smtp
            'SMTPサーバー名
            smtp.SmtpServer = "xxx.xxx.xxx"
            'ポート番号
            smtp.SmtpPort = 25
            '認証
            smtp.AuthMethod = SmtpAuthMethod.Plain
            smtp.AuthUserName = "xxxxx"
            smtp.AuthPassword = "xxxxx"
            '送信する
            smtp.Send(mail)
 
            Console.ReadLine()
        End Sub
 
        Private _smtpServer As String
        ''' <summary>
        ''' SMTPサーバー
        ''' </summary>
        Public Property SmtpServer() As String
            Get
                Return _smtpServer
            End Get
            Set(ByVal Value As String)
                _smtpServer = Value
            End Set
        End Property
 
        Private _smtpPort As Integer = 25
        ''' <summary>
        ''' ポート番号
        ''' </summary>
        Public Property SmtpPort() As Integer
            Get
                Return _smtpPort
            End Get
            Set(ByVal Value As Integer)
                _smtpPort = Value
            End Set
        End Property
 
        Private _authUserName As String
        ''' <summary>
        ''' 認証で用いるユーザー名
        ''' </summary>
        Public Property AuthUserName() As String
            Get
                Return _authUserName
            End Get
            Set(ByVal Value As String)
                _authUserName = Value
            End Set
        End Property
 
        Private _authPassword As String
        ''' <summary>
        ''' 認証で用いるパスワード
        ''' </summary>
        Public Property AuthPassword() As String
            Get
                Return _authPassword
            End Get
            Set(ByVal Value As String)
                _authPassword = Value
            End Set
        End Property
 
        ''' <summary>
        ''' SMTPの認証方法
        ''' </summary>
        Public Enum SmtpAuthMethod
            None
            Plain
            Login
        End Enum
 
        Private _authMethod As SmtpAuthMethod = SmtpAuthMethod.None
        ''' <summary>
        ''' 認証方法
        ''' </summary>
        Public Property AuthMethod() As SmtpAuthMethod
            Get
                Return _authMethod
            End Get
            Set(ByVal Value As SmtpAuthMethod)
                _authMethod = Value
            End Set
        End Property
 
        Private _stream As NetworkStream
        Private _recMsg As String
        Private boundary As String
 
        ''' <summary>
        ''' メールを送信する
        ''' </summary>
        ''' <param name="mail">送信するメール</param>
        Public Sub Send(ByVal mail As SmtpMailMessage)
            Dim soc As New TcpClient
 
            '接続
            soc.Connect(SmtpServer, SmtpPort)
            _stream = soc.GetStream()
 
            Try
                ReceiveData()
                If Not _recMsg.StartsWith("220") Then
                    Throw New ApplicationException("接続に失敗しました。")
                End If
 
                SendData("EHLO" + vbCrLf)
                ReceiveData()
                If Not _recMsg.StartsWith("250") Then
                    Throw New ApplicationException(_recMsg)
                End If
 
                '認証する
                If AuthMethod <> SmtpAuthMethod.None Then
                    Authenticate()
                End If
 
                SendData(("MAIL FROM:" + mail.From + vbCrLf))
                ReceiveData()
                If Not _recMsg.StartsWith("250") Then
                    Throw New ApplicationException(_recMsg)
                End If
 
                SendData(("RCPT TO:" + mail.To + vbCrLf))
                ReceiveData()
                If Not _recMsg.StartsWith("250") Then
                    Throw New ApplicationException(_recMsg)
                End If
 
                SendData("DATA" + vbCrLf)
                ReceiveData()
                If Not _recMsg.StartsWith("354") Then
                    Throw New ApplicationException(_recMsg)
                End If
 
                '送信データ
                Dim data As String = ""
                data += "From: " + mail.From + vbCrLf
                data += "To: " + mail.To + vbCrLf
                '件名をBase64でエンコード
                data += "Subject: =?ISO-2022-JP?B?" + _
                    GetBase64String(mail.Subject) + "?=" + vbCrLf
                data += "MIME-Version: 1.0" + vbCrLf
                data += "Content-Transfer-Encoding: 7bit" + vbCrLf
 
                data += "Content-Type: text/plain; charset=ISO-2022-JP" _
                    + vbCrLf
 
                data += vbCrLf + mail.Body.Replace( _
                    vbCrLf + "." + vbCrLf, vbCrLf + ".." + vbCrLf) _
                    + vbCrLf
 
                data += "." + vbCrLf
 
                SendData(data)
                ReceiveData()
 
                SendData("QUIT" + vbCrLf)
                ReceiveData()
            Finally
                '切断する
                soc.Close()
            End Try
        End Sub
 
        'データを受信する
        Private Sub ReceiveData()
            Dim enc As Encoding = Encoding.GetEncoding(50220)
            Dim data(1024) As Byte
            Dim len As Integer
            Dim str As String = ""
            Dim ms As New System.IO.MemoryStream
 
            'すべて受信する
            Do
                '受信
                len = _stream.Read(data, 0, data.Length)
                ms.Write(data, 0, len)
                '文字列に変換する
                str = enc.GetString(ms.ToArray())
            Loop While Not str.EndsWith(vbCrLf) OrElse _
                System.Text.RegularExpressions.Regex.IsMatch( _
                    str, "(?:^|\n)\d+-[^\r\n]*\r\n$")
 
            ms.Close()
 
            '表示
            Console.Write(("S: " + str))
 
            _recMsg = str
        End Sub
 
        'データを送信する
        Private Sub SendData(ByVal str As String)
            Dim enc As Encoding = Encoding.GetEncoding(50220)
 
            'byte型配列に変換
            Dim data As Byte() = enc.GetBytes(str)
            '送信
            _stream.Write(data, 0, data.Length)
 
            '表示
            Console.Write(("C: " + str))
        End Sub
 
        'JISでエンコードし、Base64に変換
        Private Function GetBase64String(ByVal str As String) As String
            Dim enc As Encoding = Encoding.GetEncoding(50220)
            Return Convert.ToBase64String(enc.GetBytes(str))
        End Function
 
        '認証を行う
        Private Sub Authenticate()
            If AuthMethod = SmtpAuthMethod.Plain Then
                'PLAIN
                SendData("AUTH PLAIN" + vbCrLf)
                ReceiveData()
                If Not _recMsg.StartsWith("334") Then
                    If _recMsg.StartsWith("502") Then
                        '認証の必要なし
                        Return
                    End If
                    Throw New ApplicationException(_recMsg)
                End If
 
                Dim str As String = AuthUserName + _
                    ControlChars.NullChar + AuthUserName + _
                    ControlChars.NullChar + AuthPassword
                SendData((GetBase64String(str) + vbCrLf))
                ReceiveData()
                If Not _recMsg.StartsWith("235") Then
                    Throw New ApplicationException(_recMsg)
                End If
            ElseIf AuthMethod = SmtpAuthMethod.Login Then
                'LOGIN
                SendData("AUTH LOGIN" + vbCrLf)
                ReceiveData()
                If Not _recMsg.StartsWith("334") Then
                    If _recMsg.StartsWith("502") Then
                        '認証の必要なし
                        Return
                    End If
                    Throw New ApplicationException(_recMsg)
                End If
 
                SendData((GetBase64String(AuthUserName) + vbCrLf))
                ReceiveData()
                If Not _recMsg.StartsWith("334") Then
                    Throw New ApplicationException(_recMsg)
                End If
 
                SendData((GetBase64String(AuthPassword) + vbCrLf))
                ReceiveData()
                If Not _recMsg.StartsWith("235") Then
                    Throw New ApplicationException(_recMsg)
                End If
            End If
        End Sub
    End Class
End Namespace