DoboWiki

'C#のコードを'C# to VB.NET Translator'で変換し、修正したコードです
'http://www.aspalliance.com/aldotnet/examples/translate.aspx
'
'/ <summary>
'/ 公開鍵と秘密鍵を作成して返す
'/ </summary>
'/ <param name="publicKey">作成された公開鍵(XML形式)</param>
'/ <param name="privateKey">作成された秘密鍵(XML形式)</param>
Public Shared Sub CreateKeys(ByRef publicKey As String, _
                            ByRef privateKey As String)
    'RSACryptoServiceProviderオブジェクトの作成
    '（Web Service,ASP Page,COM+の時は次のように
    'UseMachineKeyStoreを指定する）
    Dim CSPParam As New System.Security.Cryptography.CspParameters
    CSPParam.Flags = _
        System.Security.Cryptography.CspProviderFlags.UseMachineKeyStore
    Dim rsa As New _
        System.Security.Cryptography.RSACryptoServiceProvider(CSPParam)
 
    '公開鍵をXML形式で取得
    publicKey = rsa.ToXmlString(False)
    '秘密鍵をXML形式で取得
    privateKey = rsa.ToXmlString(True)
End Sub
 
'/ <summary>
'/ 公開鍵を使って文字列を暗号化する
'/ </summary>
'/ <param name="str">暗号化する文字列</param>
'/ <param name="publicKey">暗号化に使用する公開鍵(XML形式)</param>
'/ <returns>暗号化された文字列</returns>
Public Shared Function Encrypt(ByVal str As String, _
                            ByVal publicKey As String) As String
    'RSACryptoServiceProviderオブジェクトの作成
    Dim CSPParam As New System.Security.Cryptography.CspParameters
    CSPParam.Flags = _
        System.Security.Cryptography.CspProviderFlags.UseMachineKeyStore
    Dim rsa As New _
        System.Security.Cryptography.RSACryptoServiceProvider(CSPParam)
 
    '公開鍵を指定
    rsa.FromXmlString(publicKey)
 
    '暗号化する文字列をバイト配列に
    Dim data As Byte() = System.Text.Encoding.UTF8.GetBytes(str)
    '暗号化する
    '（XP以降の場合のみ2項目にTrueを指定し、OAEPパディングを使用できる）
    Dim encryptedData As Byte() = rsa.Encrypt(data, False)
 
    'Base64で結果を文字列に変換
    Return System.Convert.ToBase64String(encryptedData)
End Function
 
'/ <summary>
'/ 秘密鍵を使って文字列を復号化する
'/ </summary>
'/ <param name="str">Encryptメソッドにより暗号化された文字列</param>
'/ <param name="privateKey">復号化に必要な秘密鍵(XML形式)</param>
'/ <returns>復号化された文字列</returns>
Public Shared Function Decrypt(ByVal str As String, _
                            ByVal privateKey As String) As String
    'RSACryptoServiceProviderオブジェクトの作成
    Dim CSPParam As New System.Security.Cryptography.CspParameters
    CSPParam.Flags = _
        System.Security.Cryptography.CspProviderFlags.UseMachineKeyStore
    Dim rsa As New _
        System.Security.Cryptography.RSACryptoServiceProvider(CSPParam)
 
    '秘密鍵を指定
    rsa.FromXmlString(privateKey)
 
    '復号化する文字列をバイト配列に
    Dim data As Byte() = System.Convert.FromBase64String(str)
    '復号化する
    Dim decryptedData As Byte() = rsa.Decrypt(data, False)
 
    '結果を文字列に変換
    Return System.Text.Encoding.UTF8.GetString(decryptedData)
End Function

'/ <summary>
'/ フォームのイメージを印刷する
'/ </summary>
'/ <param name="frm">イメージを印刷するフォーム</param>
Public Sub PrintForm(ByVal frm As Form)
    'フォームのイメージを取得する
    CaptureScreen(frm)
    'フォームのイメージを印刷する
    Dim PrintDocument1 As New System.Drawing.Printing.PrintDocument
    AddHandler PrintDocument1.PrintPage, _
        AddressOf PrintDocument1_PrintPage
    PrintDocument1.Print()
End Sub
 
<System.Runtime.InteropServices.DllImport("gdi32.dll")> _
Private Shared Function BitBlt(ByVal hdcDest As IntPtr, _
    ByVal nXDest As Integer, ByVal nYDest As Integer, _
    ByVal nWidth As Integer, ByVal nHeight As Integer, _
    ByVal hdcSrc As IntPtr, _
    ByVal nXSrc As Integer, ByVal nYSrc As Integer, _
    ByVal dwRop As Integer) As Boolean
End Function
 
'フォームのイメージを保存する変数
Private memoryImage As Bitmap
 
'フォームのイメージを取得する
Private Sub CaptureScreen(ByVal frm As Form)
    Dim mygraphics As Graphics = frm.CreateGraphics()
    Dim s As Size = frm.Size
    memoryImage = New Bitmap(s.Width, s.Height, mygraphics)
    Dim memoryGraphics As Graphics = Graphics.FromImage(memoryImage)
    Dim dc1 As IntPtr = mygraphics.GetHdc()
    Dim dc2 As IntPtr = memoryGraphics.GetHdc()
    BitBlt(dc2, 0, 0, _
        frm.ClientRectangle.Width, frm.ClientRectangle.Height, _
        dc1, 0, 0, 13369376)
    mygraphics.ReleaseHdc(dc1)
    memoryGraphics.ReleaseHdc(dc2)
End Sub
 
'PrintDocument1のPrintPageイベントハンドラ
Private Sub PrintDocument1_PrintPage(ByVal sender As Object, _
        ByVal e As System.Drawing.Printing.PrintPageEventArgs)
    e.Graphics.DrawImage(memoryImage, 0, 0)
End Sub

Private Sub Form1_Load(ByVal sender As Object, _
        ByVal e As System.EventArgs) Handles MyBase.Load
    'TextBox1のLostFocusイベントハンドラを追加する
    AddHandler TextBox1.LostFocus, AddressOf TextBox1_LostFocus
End Sub
 
'LostFocusイベントハンドラ
Private Sub TextBox1_LostFocus(ByVal sender As Object, _
        ByVal e As EventArgs)
    Console.WriteLine("LostFocusイベントが発生しました。")
End Sub