DoboWiki

Imports System
Imports System.Drawing
Imports System.Windows.Forms
Imports System.Data
 
Namespace Dobon.Samples.Forms
    ''' <summary>
    ''' セルのテキスト配置を列ヘッダと別に設定できる
    ''' DataGridTextBoxColumnクラス
    ''' </summary>
    Public Class DataGridCellAlignColumn
        Inherits DataGridTextBoxColumn
        'テキストをセルに描画する際のマージン
        'これがないと、描画位置が上になりすぎる
        Private _margin As New Point(0, 2)
 
        Private _cellAlign As HorizontalAlignment = _
            HorizontalAlignment.Left
        ''' <summary>
        ''' セルのテキスト配置方法
        ''' </summary>
        Public Property CellAlign() As HorizontalAlignment
            Get
                Return _cellAlign
            End Get
            Set(ByVal Value As HorizontalAlignment)
                _cellAlign = Value
            End Set
        End Property
 
        Protected Overloads Overrides Sub Edit( _
                ByVal [source] As CurrencyManager, _
                ByVal rowNum As Integer, _
                ByVal bounds As Rectangle, _
                ByVal [readOnly] As Boolean, _
                ByVal instantText As String, _
                ByVal cellIsVisible As Boolean)
            MyBase.Edit([source], rowNum, bounds, [readOnly], _
                instantText, cellIsVisible)
            'TextBoxのテキスト配置を変更する
            Me.TextBox.TextAlign = _cellAlign
        End Sub
 
        Protected Overloads Overrides Sub Paint( _
                ByVal g As Graphics, _
                ByVal bounds As Rectangle, _
                ByVal [source] As CurrencyManager, _
                ByVal rowNum As Integer, _
                ByVal backBrush As Brush, _
                ByVal foreBrush As Brush, _
                ByVal alignToRight As Boolean)
            Dim [text] As String = _
                GetColumnValueAtRow([source], rowNum).ToString()
 
            Dim sf As New StringFormat
            '配置方法により、描画方法を変更する
            Select Case _cellAlign
                Case HorizontalAlignment.Left
                    sf.Alignment = StringAlignment.Near
                Case HorizontalAlignment.Center
                    sf.Alignment = StringAlignment.Center
                Case HorizontalAlignment.Right
                    sf.Alignment = StringAlignment.Far
            End Select
 
            sf.FormatFlags = StringFormatFlags.NoWrap
            If alignToRight Then
                sf.FormatFlags = sf.FormatFlags Or _
                    StringFormatFlags.DirectionRightToLeft
            End If
 
            '背景を塗りつぶす
            g.FillRectangle(backBrush, bounds)
 
            Dim rectf As New RectangleF( _
                bounds.X, bounds.Y, bounds.Width, bounds.Height)
            rectf.Inflate(-_margin.X, -_margin.Y)
 
            '文字列を描画する
            g.DrawString([text], _
                Me.DataGridTableStyle.DataGrid.Font, _
                foreBrush, rectf, sf)
 
            sf.Dispose()
        End Sub
    End Class
End Namespace

Namespace MyNamespace
    Public Class [MyClass]
        '列挙型
        Public Enum PublicEnum
            One
            Two
        End Enum
 
        'フィールド
        Private PrivateField As Integer
 
        'プロパティ
        Public ReadOnly Property PublicProperty() As Integer
            Get
                Return PrivateField
            End Get
        End Property
 
        'コンストラクタ
        Public Sub New(ByVal val As Integer)
            PrivateField = val
        End Sub
 
        'メソッド
        Public Overloads Function PublicMethod( _
                ByVal str As String) As String
            str = "PublicMethodが呼び出されました。" + str
            Return str
        End Function
 
        Public Overloads Function PublicMethod() As String
            Return PublicMethod("")
        End Function
    End Class
End Namespace

'Imports System.Reflection
'が宣言されているものとする
 
'MyClassクラスのTypeオブジェクトを取得する
Dim t As Type = GetType(MyNamespace.MyClass)
 
'メンバを取得する
Dim members As MemberInfo() = t.GetMembers( _
    BindingFlags.Public Or BindingFlags.NonPublic Or _
    BindingFlags.Instance Or BindingFlags.Static Or _
    BindingFlags.DeclaredOnly)
 
Dim m As MemberInfo
For Each m In members
    'メンバの型と、名前を表示する
    Console.WriteLine("{0} - {1}", m.MemberType, m.Name)
Next

'Imports System.Reflection
'が宣言されているものとする
 
'MyClassクラスのTypeオブジェクトを取得する
Dim t As Type = GetType(MyNamespace.MyClass)
 
'メソッドの一覧を取得する
Dim methods As MethodInfo() = t.GetMethods( _
    BindingFlags.Public Or BindingFlags.NonPublic Or _
    BindingFlags.Instance Or BindingFlags.Static)
 
Dim m As MethodInfo
For Each m In methods
    '特別な名前のメソッドは表示しない
    If m.IsSpecialName Then
        GoTo ContinueForEach1
    End If
 
    'アクセシビリティを表示
    'ここではIs...プロパティを使っているが、
    'Attributesプロパティを調べても同じ
    If m.IsPublic Then
        Console.Write("public ")
    End If
    If m.IsPrivate Then
        Console.Write("private ")
    End If
    If m.IsAssembly Then
        Console.Write("internal ")
    End If
    If m.IsFamily Then
        Console.Write("protected ")
    End If
    If m.IsFamilyOrAssembly Then
        Console.Write("internal protected ")
    End If
 
    'その他修飾子を表示
    If m.IsStatic Then
        Console.Write("static ")
    End If
    If m.IsAbstract Then
        Console.Write("abstract ")
    Else If m.IsVirtual Then
        Console.Write("virtual ")
    End If
 
    '戻り値を表示
    If m.ReturnType.Equals(Type.GetType("System.Void")) Then
        Console.Write("void ")
    Else
        Console.Write((m.ReturnType.ToString() + " "))
    End If
 
    'メソッド名を表示
    Console.Write(m.Name)
 
    'パラメータを表示
    Dim prms As ParameterInfo() = m.GetParameters()
    Console.Write("(")
    Dim i As Integer
    For i = 0 To prms.Length - 1
        Dim p As ParameterInfo = prms(i)
        Console.Write((p.ParameterType.ToString() + " " + p.Name))
        If prms.Length - 1 > i Then
            Console.Write(", ")
        End If
    Next
    Console.Write(")")
 
    Console.WriteLine()
 
ContinueForEach1:
Next